>	with(plots):

>	f2:=(x^4+x^3-11*x^2-9*x+18)/(x^2-3*x+2);

>	plot(f2,x=-4..4,y=-30..30,thickness=2);

In the graph above Maple has attempted to connect points on each side of a vertical asymptote.  This results in drawing something that looks a lot like the vertical asymptote.  The

vertical looking line above is not part of the graph.  The option "discont=true" prompts Maple to look for discontinuities and adjust the graph.

>	plot(f2,x=-4..4,y=-30..30,thickness=2,discont=true);

There is a removable discontinuity (hole in the graph) at x=1 (the "hole" corresponds to the point (1,24)).  If you magnify the graph including the thickness around (1,24) you get an

indication of the discontinuity.

>	eval(f2,x=0.99);

>	eval(f2,x=1.01);

>	plot(f2,x=.99..1.01,y=23.742..24.262,thickness=10,discont=true);

>	Q2:=quo(x^4+x^3-11*x^2-9*x+18,x^2-3*x+2,x);

>	f2Graph:=plot(f2,x=-10..10,y=-100..100,thickness=2,discont=true):

>	Q2graph:=plot(x^2+4*x-1,x=-10..10,y=-100..100,thickness=2,color=blue):

>	Vert2Asym1:=implicitplot(x=2,x=-10..10,y=-100..100,thickness=2,color=blue):

Below we see the graph of the function (f2) drawn in red along with its vertical asymptote drawn in blue and an "asymptotic parabola" also drawn in blue.

>	display(f2Graph,Q2graph,Vert2Asym1);

>	factor(x^4+x^3-11*x^2-9*x+18);

>	factor(x^2-3*x+2);

>	(x+2)*(x+3)*(x-1)*(x-3)/((x-2)*(x-1));

Notice that in reducing the quotient Maple did not point out that x cannot equal 1 if the reduced quotient is to be identically equal to the original.

>	f2Prime:=diff(f2,x);

>	fsolve({f2Prime},{x},x=-3..-1);

>	eval(f2,x=-2.494939671);

We can see that there is a relative minimum point at approximately (-2.494939671,-0.3055867950).

>	f2PP:=diff(f2,x,x);

>	fsolve({f2PP},{x},x=4..8);

>	eval(f2,x=4.714417617);

>	eval(f2PP,x=4.7);

>	eval(f2PP,x=4.72);

The graph looks like it may have an inflection point so I approximated the value of x where the second derivative (f2PP) equals zero.  I then checked to see if the sign of the second

derivative changed on each side of the possible inflection point.  It did.  We have an inflection point at approximately (4.714417617,32.71534092).  The inflection point and

relative minimum point are each plotted as blue crosses on the graph below.  The removable discontinuity is plotted as a small blue circle.

>	InfPt:=pointplot([4.714417617,32.71534092],symbol=cross,symbolsize=20,color=blue):

>	RelMinPt:=pointplot([-2.494939671,-.3055867950],symbol=cross,symbolsize=20,color=blue):

>	RemDisCont:=pointplot([1,24],symbol=circle,symbolsize=16,color=blue):

>	display(f2Graph,InfPt,RelMinPt,RemDisCont);

>	f2Graph2:=plot(f2,x=2..12,y=-200..200,thickness=2,discont=true):

>	display(f2Graph2,InfPt);

>